BOOT/T ;		* * * * * * * * * * * * *
 ;		*  Program by Kim Watt  *
 ;		* Breeze Computing Inc. *
 ;		*     P.O. Box  1013    *
 ;		* Berkley, Mich.  48072 *
 ;		*    (313)  288-9422    *
 ;		* * * * * * * * * * * * *
 ;
 ;
 	ORG	4200H
 ENTRY	CALL	DISPLY
 	DEFW	1F1CH
 	DEFM	'- Breeze Game Loader -'
 	DEFW	0D0DH
 	DEFM	'1.  Simon'
 	DEFB	0DH
 	DEFM	'2.  Capture'
 	DEFW	0D0DH
 	DEFM	'Select game ! '
 	DEFB	0
 WHICH	LD	A,(3810H)
 	CP	2
 	JR	Z,SIMON
 	CP	4
 	JR	NZ,WHICH
 	LD	DE,0500H
 	JR	LOAD
 SIMON	LD	DE,0100H
 LOAD	CALL	SELECT
 	LD	BC,0
 	CALL	60H
 	LD	BC,4500H
 	LD	HL,20
 	CALL	MREAD
 	JR	NZ,ERROR
 	JP	4500H
 DISPLY	POP	DE
 DISLP	LD	A,(DE)
 	INC	DE
 	OR	A
 	JR	Z,DISDN
 	CP	20H
 	JR	C,CARRET
 	LD	HL,(4020H)
 	LD	(HL),A
 	CP	(HL)
 	JR	Z,DISOK
 	SUB	20H
 	LD	(HL),A
 DISOK	INC	HL
 	LD	(4020H),HL
 	JR	DISLP
 CARRET	PUSH	DE
 	CALL	33H
 	POP	DE
 	JR	DISLP
 DISDN	PUSH	DE
 	RET
 MREAD	PUSH	HL
 	CALL	READ
 	POP	HL
 	JR	NZ,ERROR
 	DEC	L
 	RET	Z
 	INC	E
 	LD	A,E
 	SUB	0AH
 	JR	NZ,MREAD
 	LD	E,A
 	INC	D
 	JR	MREAD
 READ	PUSH	BC
 	CALL	READ1
 	POP	HL
 	RET	Z
 	LD	B,H
 	LD	C,L
 READ1	LD	(37EEH),DE
 	CALL	SELECT
 	LD	HL,37ECH
 	LD	(HL),1BH
 	PUSH	AF
 	POP	AF
 	PUSH	AF
 	POP	AF
 SEEK	CALL	SELECT
 	LD	A,(HL)
 	RRCA
 	JR	C,SEEK
 	LD	(HL),80H
 	PUSH	DE
 	LD	DE,37EFH
 	PUSH	BC
 	POP	BC
 	NOP
 	JR	STATCK
 DONECK	RRCA
 	JR	NC,DONERD
 STATCK	LD	A,(HL)
 	BIT	1,A
 	JR	NZ,DONECK
 	LD	A,(DE)
 	LD	(BC),A
 	INC	BC
 	JR	STATCK
 DONERD	LD	A,(HL)
 	AND	1CH
 	POP	DE
 	RET	Z
 	LD	(HL),0D0H
 	RET
 SELECT	LD	A,1
 	LD	(37E1H),A
 	RET
 ERROR	CALL	DISPLY
 	DEFW	1F1CH
 	DEFM	'-DISK ERROR-'
 	DEFB	0
 	CALL	2BH
 	JP	ENTRY
 	END	ENTRY
 	AND	1CH
 	POP	DE
 	RET	Z
 	LD	(HL),0D0H
 	RET
 SE